Fremdschlüssel Aktion Check

admin — Mon, 29 Dec 2008 08:10:23 +0100

SELECT
    OBJECTPROPERTY(O.[OBJECT_ID], 'CnstIsUpdateCascade') AS updcascade,
    OBJECTPROPERTY(O.[OBJECT_ID], 'CnstIsDeleteCascade') AS delcascade,
    [name]
FROM
    sys.objects O
WHERE
    OBJECTPROPERTY(O.[OBJECT_ID], 'IsForeignKey') = 1 AND
    (OBJECTPROPERTY(O.[OBJECT_ID], 'CnstIsUpdateCascade') = 1 OR OBJECTPROPERTY(O.[OBJECT_ID], 'CnstIsDeleteCascade') = 1)
ORDER BY 1 DESC, 3

Durchschnittliche Zeilenlänge anzeigen

admin — Mon, 29 Dec 2008 08:05:29 +0100

DECLARE @TableID int
SELECT @TableID = OBJECT_ID ('Enter TableName here')

SELECT 
	OBJECT_NAME (IXStats.[object_id]) AS ObjectName,
	IXStats.index_type_desc,
	IXStats.avg_record_size_in_bytes
FROM 
    sys.dm_db_index_physical_stats (DB_ID(), @TableID, OBJECTPROPERTY (@TableID, 'TableHasClustIndex'), 0, 'SAMPLED') IXStats

Feststellen, ob eine Tabelle einen Trigger besitzt

admin — Thu, 11 Dec 2008 13:07:54 +0100

SELECT
    CASE 
        WHEN OBJECTPROPERTY(OBJECT_ID('dbo.BookSource'), 'HasAfterTrigger') + 
            OBJECTPROPERTY(OBJECT_ID('dbo.BookSource'), 'HasInsteadOfTrigger') > 0
        THEN 'Trigger vorhanden' 
        ELSE  'Kein Trigger vorhanden' 
    END
GO
IF EXISTS (SELECT 1
        FROM
            sys.triggers T
        WHERE
            T.parent_id = OBJECT_ID ('dbo.BookSource'))
    SELECT 'Trigger vorhanden' 
ELSE  
    SELECT 'Kein Trigger vorhanden'

Informationen zu Trigger

admin — Thu, 04 Dec 2008 07:02:35 +0100

SELECT
    T.[name] AS Trigger_Name,
	OBJECT_NAME(T.parent_id) AS Table_Name,
	TE.type_desc,
	T.create_date
FROM
    sys.triggers T
    JOIN
    sys.trigger_events TE ON T.[object_id] = TE.[object_id]

Objektberechtigungen anzeigen

admin — Tue, 21 Oct 2008 14:40:49 +0200

DECLARE @string sysname;

SELECT @string = '< search string >';

SELECT
    OBJECT_NAME(major_id) AS ObjectName, 
    USER_NAME(grantor_principal_id) AS Grantor, 
    USER_NAME(grantee_principal_id) AS Grantee, 
    p.permission_name
FROM
    sys.database_permissions p
WHERE
    OBJECTPROPERTY(major_id, 'IsMSSHipped') = 0 AND 
    USER_NAME(grantee_principal_id) = @string
ORDER BY
    OBJECT_NAME(major_id), USER_NAME(grantee_principal_id), permission_name;

WA_Sys Statistiken löschen

admin — Tue, 23 Sep 2008 10:38:54 +0200

SET NOCOUNT ON;
DECLARE @TempStats TABLE (StatsName varchar(500));
DECLARE @StatsName varchar(500);
DECLARE @sql varchar(MAX);

INSERT INTO @TempStats
    (StatsName)
SELECT    
    OBJECT_NAME([object_id]) + '.' + [name]
FROM 
    sys.stats S
WHERE
    OBJECTPROPERTY([object_id], 'IsMSShipped') = 0 AND
    [NAME] LIKE '_WA_Sys%';

SELECT 
    @StatsName = MIN(StatsName)
FROM
    @TempStats;

WHILE @StatsName IS NOT NULL
BEGIN
    SELECT @sql = 'DROP STATISTICS ' + @StatsName;
    EXEC (@sql);
    
    PRINT 'Deleted statistics: ' + @StatsName;
    
    DELETE
Weiterlesen

Zeichenfolge im SQL Code finden

admin — Mon, 22 Sep 2008 15:05:11 +0200

DECLARE @codesnippet varchar(100);

SET @codesnippet = 'EnterStringHere';

SELECT
    O.type_desc AS ObjectType,
    (LEFT(OBJECT_NAME(M.[object_id]), 50)) AS ObjectName
FROM
    sys.sql_modules M
    JOIN
    sys.objects O ON M.[object_id] = O.[object_id]
WHERE
    definition LIKE '%' + @codesnippet + '%'
    AND
    OBJECTPROPERTY(M.[object_id], 'IsMSShipped') = 0
ORDER BY
    ObjectName;

Spaltenname über alle Tabellen einer Datenbank suchen

tosc — Thu, 18 Sep 2008 11:13:53 +0200


DECLARE @COL_NAME NVARCHAR(50)
SET @COL_NAME = '%VBELN%'

SELECT     DB_NAME(DB_ID()) AS Datenbank, 
                B.name AS TabllenName, 
                A.name AS SpaltenName
FROM        sys.syscolumns AS A INNER JOIN
                      sys.sysobjects AS B ON A.id = B.id
WHERE     (A.name LIKE @COL_NAME) AND (B.type LIKE 'U%')

Indexfragmentierung anzeigen

admin — Mon, 01 Sep 2008 13:22:56 +0200

SELECT 
    DB_NAME(DB_ID()) AS DatabaseName,
    O.[name] AS TabellenName,
    SIX.[Name] AS IndexName,
    IXStats.avg_fragmentation_in_percent,
    SIX.type_desc AS Indextyp
FROM 
    sys.dm_db_index_physical_stats (DB_ID(), NULL, NULL, NULL, NULL) IXStats
    JOIN 
    sys.indexes SIX ON IXStats.[object_id] = SIX.[object_id] AND IXStats.index_id = SIX.index_id
    JOIN
    sys.objects O ON SIX.[object_id] = O.[object_id]
WHERE 
    IXStats.database_id = DB_ID()
ORDER BY 
    IXStats.avg_fragmentation_in_percent DESC

Plan Reuse abfragen

admin — Fri, 29 Aug 2008 14:04:35 +0200

DECLARE @string varchar(500)
SELECT
    @string = '%SomeString%'
 SELECT 
    SCP.usecounts, SCP.cacheobjtype, SCP.objtype, 
    [Statement].text, 
    Executionplan.query_plan 
FROM
    sys.dm_exec_cached_plans SCP
    OUTER APPLY sys.dm_exec_sql_text(plan_handle) [Statement]
    OUTER APPLY sys.dm_exec_query_plan(plan_handle) Executionplan
WHERE
    Statement.[text] LIKE @string AND
    SCP.cacheobjtype ='Compiled Plan' AND 
    SCP.objtype = 'proc'

Code Library